トップページ > .CELスクリプトガイド > .CELスクリプトコマンド一覧

.CELスクリプトコマンド一覧


cancel


引数:
無し

gototrackなどのコマンドやfollowsynchronousなどのモード指定をすべて解除します。キーボードでEscを押したのと同様です。


center


引数:
time <数値> (デフォルト 1.0

time選択された天体を画面の中央に移動させる時間[秒]

選択した天体を画面の中央に移動させます。キーボードでGを押したのと同じ動作です。
selectコマンドで天体を指定してからcenterコマンドを使用してください。
引数timeに負数を使用しないでください。Celestiaがフリーズします。この場合はEscを押してキャンセルしてください。

例:
地球を選択し、5.5秒で画面の中央に移動させる場合


	select { object "Sol/Earth" }
	center { time 5.5 }


changedistance


引数:
duration <数値> (デフォルト 1.0
rate <数値> (デフォルト 0.0

duration選択された天体の距離を変更するのにかける時間[秒]
rate距離を変更する際のスピード。5、6位の小数値が妥当。負数で天体に接近し、正数で遠ざかる。

選択した天体との距離を変更します。
selectコマンドで天体を指定してからchangedistanceコマンドを使用してください。
durationに負数を設定するとコマンドは無視されます。

例:
地球を選択してそこまで行き、2.5秒で遠ざかる場合


	select { object "Sol/Earth" }
	goto   { time 3 }
	wait   { duration 3 }
	changedistance { duration 2.5 rate 0.5 }
	wait   { duration 2.5 }


chase


引数:
無し

モードをchaseに設定します。選択した天体の公転に同期して追尾します。「"」キーを押したのと同様の動作をします。
事前に天体を選択している必要があります。

例:
月を選択し、chaseモードで設定した後に2秒で航行する場合


	select { object "Sol/Earth/Moon" }
	chase  { }
	goto   { time 2 }
	wait   { duration 2 }


cls


引数:
無し

printコマンドで表示された文字列を消去します。あまり使い道は無いようです。

例:


	cls { }


follow


引数:
無し

モードをfollowに設定します。天球を固定して選択した天体を追尾します。「F」キーを押したのと同様の動作をします。
事前に天体を選択している必要があります。

例:
火星を選択し、followモードに設定した後に2秒で移動する場合


	select { object "Sol/Mars" }
	follow  { }
	goto   { time 2 }
	wait   { duration 2 }


goto


引数:
time <数値> (デフォルト 1.0
distance <数値> (デフォルト 5.0)
upframe <文字列> (デフォルト "universal")
up <ベクトル> (デフォルト Y [ 0 1 0 ])

time目的の天体に到達するまでの時間[秒]
distance設定する天体との距離[天体の半径=1]。天体の中心からの距離で計算するため、設定したい天体からの距離+1の数値をdistanceに設定する。 例えば、半径10000kmの天体でdistanceに6を指定した場合、天体からの距離は50000kmになる。
ちなみに、地球(半径6378.1km)から1000000kmの距離に設定したい場合のdistanceの値は
(1000000 / 6378.1) + 1 = 157.7865となる。
※0で天体の中心に移動できるが、正しく認識しない場合もあり、お勧めしない。
※1を指定すると天体の表面に移動。画面が乱れるおそれあり。
upframe次のうちどれか一つを必ず指定してください。
  • chase - Chase
  • equliptical
  • equatorial - Follow
  • geographic - Sync Orbit
  • lock - Lock
  • observer - 何も選択されて無い状態
  • universal
upX [ 1 0 0 ]、Y [ 1 0 0 ]、Z [ 1 0 0 ]で指定。

selectコマンドで天体を指定してからgotoコマンドを使用してください。
printのような非動作系コマンドが視点移動中に使用できます。
※時間の引数を持つコマンドを次に実行する場合、直後にwaitコマンドを挿入し、引数durationの値をこのコマンドのそれ以上の値に設定してください。指定した視点移動がされず、次の行のコマンドが実行されます。
引数timeに負数を使用しないでください。Celestiaがフリーズします。この場合はEscを押してキャンセルしてください。

例:
火星を選択して5秒で航行する場合


	select { object "Mars" }
	goto   { time 5 }
	wait   { duration 5 }
無効な例:次のスクリプトは正しく動作しません。gotoコマンドのtime以上の長さのdurationwaitコマンドを直後に挿入しないとコマンドは無視されます。次の場合、火星は表示されず、地球のみが表示されます。

	select { object "Mars" }
	goto   { time 5 }
	select { object "Earth" }
	goto   { time 3 }
	wait   { duration 8 }
スクリプトを正しく動かすには次の通りにしてください。

	select { object "Mars" }
	goto   { time 5 }
	wait   { duration 5 }
	select { object "Earth" }
	goto   { time 3 }
	wait   { duration 3 }
火星へ航行する途中にprintで文字列を表示する事もできます。

	select { object "Mars" }
	goto   { time 5
		distance 8.5
		upframe "follow"
		up [0 1 0] }

	print  { text "We're on our way to Mars."
		row -3 column 1
		duration 5 }
	wait   { duration 5 }


gotoloc


引数:
time <数値> (デフォルト 1.0
position <ベクトル> (デフォルト [ 0 1 0 ])
xrot <数値> (デフォルト 0.0
yrot <数値> (デフォルト 0.0
zrot <数値> (デフォルト 0.0
または
time <数値> (デフォルト無し)
x <Base64> (デフォルト無し)
y <Base64> (デフォルト無し)
z <Base64> (デフォルト無し)
ow <数値> (デフォルト無し)
ox <数値> (デフォルト無し)
oy <数値> (デフォルト無し)
oz <数値> (デフォルト無し)

time目的の天体に到達するまでの時間[秒]
position現在のモードでの、目的の天体まで位置をkm単位でX軸、Y軸、Z軸をそれぞれ設定。
universal座標系以外では[ 0 0 0 ]は天体の中心を表す。
なお、kmの値は天体の半径を考慮した値となる。例えば、地球の表面より100000kmの位置を指定したい場合、地球の半径が6378.1kmなので、設定する値は6378.1+100000で106378.1kmとなる。
xrot
yrot
zrot
視点の方向を定める。それぞれピッチ、ヨー、ロールに対応。
関連するコマンド:
X/ピッチ (↑・↓キー)
Y/ヨー (NumLock がONの時: テンキーの4、6)
Z/ロール (←・→キー)
x
y
z
ow
ox
oy
oz
Cel://URLより位置を作成したい時に使用。
Cel://URL内の ?x= &y= &z= &ow= &ox= &oy= &oz=にそれぞれ対応。

現在設定している天体に時間timeで指定された位置に移動します。
事前にモードを設定しておいてください。このコマンドではモードを変更できません。
引数timeに負数を使用しないでください。Celestiaがフリーズします。この場合はEscを押してキャンセルしてください。

例:地球から100000km離れた位置に移動する場合


	select    { object "Sol/Earth" }
	center    { }
	follow    { }
	
	gotoloc   { time 2
	            position [0 106378.1 0]
	            xrot 90
	            yrot 0
 	           zrot 0 }
	wait      { duration 2 }
次のスクリプトはgotolocを使った少し複雑な例となっております。
地球へ向かい、日本の上空まで移動します。すると左上に太陽、右上に月が見えてきます。
{
  cancel { }

  renderflags { clear "boundaries|comettails|constellations" }
  renderflags { clear "eclipseshadows|orbitspointstars|ringshadows" }
  renderflags { clear "automag|grid" }
  renderflags { set   "cloudmaps|galaxies|nightmaps|planets|stars" }
  renderflags { set   "atmospheres|markers" }

  labels    { clear "planets|moons|spacecraft|asteroids" }
  labels    { clear "constellations|stars|galaxies" }

# 時間を停止し、日時を設定。 
  timerate  { rate 0 }
  time      { jd 2452874.992638889 }

# 月を青い四角でマーキング。
  unmarkall { }
  mark      { object "Sol/Earth/Moon"
              size   20.0
              color  [0 0 1]
              symbol "square" }

# 視界の広さを設定。
  set       { name "FOV" value 47.0 }
 
  select    { object "Sol/Earth" }
  center    { }
  follow    { }

# 位置設定: +7000km-X, +9000km-Y, +11000km-Z
# ピッチ 上に +13X, ヨー 右に -32Y, ロール 左に -95Z
  gotoloc   { time 2
              position [7000 9000 11000]
              xrot 13
              yrot -32
              zrot -95 }
  wait      { duration 2 }

  print     { text "Blue square is the Moon ---"
              row -24 column 32 duration 3 }
  wait      { duration 3 }

#******************************************
  print { text "First result done." 
          duration 2  row -3  column  2 }
  wait { duration 2 }
#******************************************

  cancel { }
  gotoloc { 
    time 2 
    x "wJjebddBM3XLDA"
    y "Z2/b0Q34Pw"
    z "GShiyVOKuxUI"
    ow 0.954531
    ox 0.112769
    oy -0.272262
    oz -0.045019 }
 
#******************************************
  print { text "Second result done." 
          duration 2  row -3  column  2 }
  wait { duration 2 }
#******************************************

}


gotolonglat


引数:
time <数値> (デフォルト 1.0
distance <数値> (デフォルト 5.0)
up <ベクトル> (デフォルト Y [ 0 1 0 ])
longitude <数値> (デフォルト無し)
latitude <数値> (デフォルト無し)

time目的の天体に到達するまでの時間[秒]
distance設定する天体との距離[天体の半径=1]。天体の中心からの距離で計算するため、設定したい天体からの距離+1の数値をdistanceに設定する。 例えば、半径10000kmの天体でdistanceに6を指定した場合、天体からの距離は50000kmになる。
ちなみに、地球(半径6378.1km)から1000000kmの距離に設定したい場合のdistanceの値は
(1000000 / 6378.1) + 1 = 157.7865となる。
※0で天体の中心に移動できるが、正しく認識しない場合もあり、お勧めしない。
※1を指定すると天体の表面に移動。画面が乱れるおそれあり。
upX [ 1 0 0 ]、Y [ 1 0 0 ]、Z [ 1 0 0 ]で指定。
longitude
latitude
天体上の位置を指定[0〜360゚]。
longitude:経度を指定。正数で東経、負数で西経。
latitude:緯度を指定。正数で北緯、負数で南緯。

selectコマンドで天体を指定してからgotolatコマンドを使用してください。
printのような非動作系コマンドが視点移動中に使用できます。
※時間の引数を持つコマンドを次に実行する場合、直後にwaitコマンドを挿入し、引数durationの値をこのコマンドのそれ以上の値に設定してください。指定した視点移動がされず、次の行のコマンドが実行されます。
引数timeに負数を使用しないでください。Celestiaがフリーズします。この場合はEscを押してキャンセルしてください。

例:
東京上空に視点を向ける場合


select      { object "Sol/Earth" }
synchronous { }
gotolonglat { time 5
              distance 3
              up [0 1 0]
              longitude 139.8
              latitude 35.7 }
print       { text "Traveling to Tokyo, Japan."
              row -3  column 1  duration 5 }
wait        { duration 5 }
print       { text "Hovering over Tokyo, Japan."
              row -3  column 1  duration 5 }
wait        { duration 5 }


lookback


引数:
無し

視点を180゚切り替えます。

例:


	lookback { }


mark


引数:
object <文字列> (デフォルト無し)
size <数値> (デフォルト 10.0
color <ベクトル> (デフォルト [ 1 0 0 ](赤))
symbol <文字列> (デフォルト "diamond")

objectマーキングする天体名
sizeマーキングの直径(ピクセル)
colorマーキングの色を設定。ベクトルの値はそれぞれR(赤)、G(緑)、B(青)に対応。
数値は0から1の間で設定。1以上の値を設定した場合、1とみなされる。
例:
黒:[ 0 0 0 ]
赤:[ 1 0 0 ](デフォルト)
緑:[ 0 1 0 ]
青:[ 0 0 1 ]
黄:[ 1 1 0 ]
白:[ 1 1 1 ]
symbolマーキングの形。次のうちのいずれかで指定。
  • diamond - 菱形
  • plus - 十字
  • square - 正方形
  • triangle - 三角形
  • x - ×印

選択した天体を指定した色・形でマーキングします。
目的の天体が既にマーキングされている、あるいはマーキングされているかどうか不明な場合は、必ずunmarkコマンドを実行してください。

例:地球を緑の×印でマーキング


	unmark { object "Sol/Earth" }
	mark   { object "Sol/Earth"
		size 15
		color [0 1 0]
		symbol "x" }


move


引数:
duration <数値> (デフォルト無し)
velocity <ベクトル> (デフォルト無し)

duration継続時間[秒]
velocity移動速度[km/s]

画面中央の方向へ視点を進めます。durationで継続時間、velocityで速度を与えます。
尚、waitコマンドは不要です。 durationに負数を設定するとコマンドは無視されます。

例:
秒速100,000kmで10秒間移動する場合


	move { duration 10 velocity 100000 }


orbit


引数:
duration <数値r> (デフォルト 1.0
rate <数値> (デフォルト 0.0)
axis <ベクトル> (デフォルト無し)

duration継続時間[秒]
rate回転速度。正数、および負数を指定。正数には"+"は不要。尚回転角度はduration * velocity[゚]となる。
axis回転軸。選択している天体を軸[ X Y Z ]で周回。X、Y、Zには1か0の値を設定。
[ 1 0 0 ]で画面の水平方向を軸として回転。
[ 0 1 0 ]で画面の垂直方向を軸として回転。
[ 0 0 1 ]で画面奥から手前方向を軸として回転。
組み合わせて[ 1 0 1 ]という軸で回転も可能。

選択した天体を周回します。durationに負数を設定するとコマンドは無視されます。

例:
土星を12秒周回する場合


	select { object "Sol/Saturn" }
	center { }
	goto { time 3 distance 8 up [0 1 0] upframe "equatorial" }
	wait { duration 3 }
	orbit { axis[ 0 1 0 ] rate 30 duration 12 }


preloadtex


引数:
object <文字列> (デフォルト無し)

objectパスではなく、ファイル名のみを記述。内部で自動検索される。.sscファイルの置いてある場所により必ずしも指定されたテクスチャが表示されない事もある。
拡張子指定に".*"を使用できる。

読み込むテクスチャのファイルサイズによってはwaitコマンドを直後に挿入した方が良い場合もあります。複数のテクスチャ、あるいは大きなサイズのテクスチャを読み込む場合はwaitコマンドの使用が推奨されます。 この場合、waitコマンドの継続時間は読み込むテクスチャのサイズに応じてスクリプトを何回かテストして最適な値を決めてください。

例:
"mars.jpg"をプリロードする場合


	preloadtex { object "mars.jpg" }


print


引数:
text <文字列> (デフォルト無し)
origin <文字列> (デフォルト "bottomleft")
duration <数値> (デフォルト 1.0
row <数値> (デフォルト 0
column <数値> (デフォルト 0

text表示したい文字列を""で囲って記述。"\n"なども使用できる。
origin文字列を表示する場所を指定。
  • bottom - 画面下部中央
  • bottomleft - 画面左下
  • bottomright - 画面右下
  • center - 画面中央
  • left - 画面中央左
  • right - 画面中央右
  • top - 画面上部中央
  • topleft - 画面左上
  • topright - 画面右上
なお、bottomrightrighttoprightの場合、column値を負の値にしないと文字列は画面の外に出てしまう。
duration文字を表示する時間[秒]。
row文字列を表示する縦位置を指定。originで指定した位置よりどの位ずらすかを記述する。
正数で下方に、負数で上方に表示。
column文字列を表示する横位置を指定。originで指定した位置よりどの位ずらすかを記述する。
正数で右方に、負数で左方に表示。

printコマンドを使用する場合には直後にwaitコマンドを挿入し、引数durationの値をprintコマンドのそれ以上の値に設定してください。文字列が表示されません。
durationに負数を設定するとコマンドは無視されます。

例:
"Hello Universe!"を1秒間、画面下から3行分、左から2列分ずらして表示する場合


	print { text "Hello Universe!"  row -3  column 2 }
	wait  { duration 1 }
例:
"Hello"を1行目、"Universe!"を2行目に5秒間、画面下から5行分、左から2列分ずらして表示する場合

	print { text  "Hello\nUniverse!"
	origin "left"
	duration 5
	row -5
	column 2 }
	wait  { duration 5 }


renderflags


引数:
set <文字列> (デフォルト無し)
clear <文字列> (デフォルト無し)

画面に表示される天体名や軌道などの表示のON/OFFを設定。「set "automag"」の様に「""」で囲って指定。複数設定する場合は「set "automag|atomospheres"」の様に「|」で区切って指定します。

例:


	renderflags { set "automag|atmospheres|nightmaps" }
	renderflags { set "boundaries|galaxies|markers" }

rotate


引数:
duration <数値> (デフォルト 1.0
rate <数値> (デフォルト 0.0)
axis <ベクトル> (デフォルト無し)

duration継続時間[秒]
velocity回転速度。正数、および負数を指定。正数には"+"は不要。尚回転角度はduration * velocity[゚]となる。
axis回転軸。選択している天体を軸[ X Y Z ]で周回。X、Y、Zには1か0の値を設定。
[ 1 0 0 ]で画面の水平方向を軸として回転。
[ 0 1 0 ]で画面の垂直方向を軸として回転。
[ 0 0 1 ]で画面の奥行方向を軸として回転。
組み合わせて[ 1 0 1 ]という軸で回転も可能。

視点を回転させます。事前に天体を選択している必要があります。durationに負数を設定するとコマンドは無視されます。

例:
Z軸を中心として右側(rate値を正の値にするとこうなる)に5秒間回転


	rotate { duration 5
		rate 10
		axis [ 0 0 1 ] }
	wait { duration 5 }

select


引数:
object <文字列> (デフォルト無し)

object恒星、惑星、衛星、小惑星、彗星、銀河・星雲、人工天体など、選択する天体の名称。

天体を選択します。
太陽系外の場所から太陽系内の天体を選択する場合、"Sol/"に続けて目的の天体を選択してください。
※入力ミスなども含め、実在しない天体を選択しようとした場合、選択された天体が「無し」の状態で次のコマンドが実行されます。

例:


	select { object "M33" }      #(M33を指定)
	select { object "Mars" }     #(太陽系内より火星を指定する場合)
	select { object "Sol/Mars" } #(太陽系外より火星を指定する場合)

set


引数:
name <文字列> (デフォルト無し)
name <数値>、<文字列> (デフォルト 0.0 または ""(空文字列))

name次のうちどれか一つを必ず指定してください。
  • MinOrbitSize -
  • AmbientLightLevel - 反射光の強さを設定(0.01.0)
  • FOV - 視界の広さ。現在のウィンドウサイズから計算される。
  • StarDistanceLimit - どのくらい遠方の恒星まで表示するか[光年]。(デフォルト:1000000
  • StarStyle - 恒星の表示方法を変更する。fuzzypointspointsscaleddiscsより指定。
valuenameで指定したパラメータの値を指定。

例:


	set { name "FOV"       value 35.5 }
	set { name "StarStyle" value "points" }

setfaintesautomag45deg


引数:
magnitude <数値> (デフォルト 8.5)

magnitude自動限界可視等級調整がONの時に、視界が45°(=1.00x)の時の限界可視等級を、1.015.0の値より設定。

例:


	setfaintestautomag45deg { magnitude 9.0 }

setframe


引数:
ref <文字列> (デフォルト無し)
target <文字列>、<文字列> (デフォルト無し)
coordsys <文字列>、<文字列> (デフォルト "universal")

ref(1番目の)天体を指定。
target2番目の天体を指定。lockの様な、天体を2つ指定する場合に用いる。
coordsys次のうちどれか一つを必ず指定してください。
  • chase - Chase
  • ecliptical
  • equatorial - Follow
  • geographic - Sync Orbit
  • lock - Lock
  • observer
  • universal - 何も選択されて無い状態

FollowやSync Oribitなどのモードを設定します。

例:
Lockモードで地球と月を表示する場合


	setframe { ref "Sol/Earth"
		   target "Sol/Earth/Moon"
		   coordsys "lock" }

setorientation


引数:
angle <数値> (デフォルト無し)
axis <数値> (デフォルト無し)
または
ow <数値> (デフォルト無し)
ox <数値> (デフォルト無し)
oy <数値> (デフォルト無し)
oz <数値> (デフォルト無し)

angle
axis
favorites.cel内のangleおよびaxisパラメータに対応しています。
ow
ox
oy
oz
Cel://URL内の&ow=、&ox=、&oy=、&oz=パラメータに対応しています。

Cel://URLより視点を作成したい場合に使用します。モードや位置なども設定する必要があります(seturlの項も参照)

例:


	setorientation {
		angle 0.945208
		axis  [ 0.81466 -0.570975 -0.101573 ] }

	setorientation { 
		ow 0.090610 
		ox -0.494683 
		oy 0.860207 
		oz -0.084397 }


setposition


引数:
base <ベクトル> (デフォルト無し)
offset <ベクトル> (デフォルト無し)
または
x <Base64> (デフォルト無し)
y <Base64> (デフォルト無し)
z <Base64> (デフォルト無し)

base
offset
favorites.cel内のbaseおよびoffsetパラメータに対応しています。
x
y
z
Cel://URL内の?x=、&y=、&z=パラメータに対応しています。

Cel://URLより位置を作成したい場合に使用します。モードや視点なども設定する必要があります(seturlの項も参照)

例:


	setposition {
	base [ -64132.43  47355.11  196091.57 ]
	offset [ 0  0  -1.52e-005 ] }

	setposition { 
		x "AMDCXoJK/3+IyGgR8f///w"
		y "BvP2LRdAAAD/n5UGCw"
		z "VUrGoeQJ+/8DyvenLQ" }


setsurface


引数:
name <文字列> (デフォルト無し)

nameテクスチャのファイル名自身ではなく、AltSurfaceで定義されたテクスチャを読み込みます。

現在選択された天体のテクスチャを変更することができます。AltSurfaceが定義されている必要があります。
例えばAltSurfaceで"earth2.jpg"というテクスチャを"Earth-2"という名前で指定する場合は、solarsys.sscファイル内の"Earth" "Sol"項を


AltSurface "Earth-2" "Sol/Earth"
{
  Texture "earth2.jpg"
}
としてください。
なお、事前にselectコマンドで天体が選択されている必要があります。

例:


	setsurface { name "limit of knowledge" }

	setsurface { name "Earth-2" }


setvisibilitylimit


引数:
magnitude <数値> (デフォルト 6.0)

magnitude自動限界可視等級調整がOFFの場合、限界可視等級を調整します。

自動限界可視等級調整がOFFの場合、限界可視等級を調整します。1.015.0の間で指定できます。

例:


	setvisibilitylimit { magnitude 6.5 }


seturl


引数:
url <文字列> (デフォルト無し)

urlCel://URLを指定します。

指定したCel://URLの状態にします。なお、モード、時刻、位置、視点など全ての状態がCel://URLに記述された通りになります。

例:


	seturl { url
		 "cel://Follow/Sol/2002-09-01T16:58:51.32378?x=AAAAAMCrktOdILb5/////w
		&y=CkxgAADEXts7E7HX/////w&z=VcpQAAAAAAAAAMIy/////w&ow=0.090610
		&ox=-0.494683&oy=0.860207&oz=-0.084397
		&select=Sol&fov=49.499992&ts=1.000000<d=0&rf=6043&lm=0" }

主なCel://URLの例:
日食
cel://Freeflight/2004-01-23T14:16:37.53441?x=QGcgesLkFj+1DA&y=IGXjwESpGv///////////w&z=Fbs1esfXhe7y/////////w&ow=0.231217&ox=-0.566846&oy=0.772273&oz=0.169759&select=Sol:Earth:Moon&fov=4.098599&ts=0.000000<d=0&rf=68503&lm=49152

月と地球の日面通過
cel://PhaseLock/Sol:Earth/Sol:Earth:Moon/2004-01-21T17:41:47.40987?x=AACt9VF45j26Cg&y=9W04W6+z8kE&z=VUqNIERs1NWX/P///////w&ow=0.153437&ox=0.784752&oy=0.560930&oz=-0.214428&select=Sol:Earth:Moon&fov=0.000976&ts=100.000000<d=0&rf=2967&lm=49158

太陽に映える国際宇宙ステーション
cel://PhaseLock/Sol:Earth:ISS/Sol/2004-01-21T20:32:57.17702?x=+BwvJlcrcqO1DA&y=YMaF/EDm6////////////w&z=EuvkSMOMmK7y/////////w&ow=0.221298&ox=0.542102&oy=0.796562&oz=-0.150474&select=Sol:Earth:ISS&fov=0.479170&ts=10.000000<d=0&rf=68503&lm=49158

国際宇宙ステーションより日の出を臨む
cel://PhaseLock/Sol:Earth:ISS/Sol/2004-01-21T23:37:16.65668?x=VXeuKd/4q5u1DA&y=4oqqiviL7P///////////w&z=mNTz/TxEPLPy/////////w&ow=0.129734&ox=-0.846240&oy=0.441594&oz=0.268405&select=Sol&fov=8.524273&ts=10.000000<d=0&rf=2967&lm=49152

国際宇宙ステーションより日の出を臨む 2
cel://PhaseLock/Sol:Earth:ISS/Sol/2004-01-21T23:37:44.04313?x=m6kFYyBup5u1DA&y=6WrIUIH+6////////////w&z=UIemtceAQLPy/////////w&ow=0.123742&ox=-0.854558&oy=0.441435&oz=0.244036&select=Sol&fov=1.972328&ts=1.000000<d=0&rf=2967&lm=49152

国際宇宙ステーションより日の出を臨む 3
cel://PhaseLock/Sol:Earth:ISS/Sol/2004-01-21T23:37:43.95277?x=Fi7Q079vp5u1DA&y=NGnFKfP+6////////////w&z=Prk+BbF5QLPy/////////w&ow=0.123742&ox=-0.854558&oy=0.441435&oz=0.244036&select=Sol&fov=1.972328&ts=1.000000<d=0&rf=2967&lm=49152

国際宇宙ステーションより日の入りを臨む
cel://PhaseLock/Sol:Earth:ISS/Sol/2004-01-22T00:33:37.32971?x=dyxw16Pmkpm1DA&y=oLa0vUflEQ&z=0bGSliRpg7Ty/////////w&ow=0.129839&ox=-0.846187&oy=0.441496&oz=0.268683&select=Sol&fov=8.524272&ts=10.000000<d=0&rf=2967&lm=49152


synchronous


引数:
無し

モードをgeographic(Sync Orbit)に設定します。このモードでは天体の自転に同期して回転します。
なお、selectで天体が指定されている必要があります。

例:


	select { object "Sol/Earth" }
	synchronous { }


time


引数:
jd <数値> (デフォルト無し)
または
utc <文字列> (標準時、デフォルト無し)

jd有効なユリウス日を指定。
utc有効な日時をYYYY-MM-DDTHH:MM:SS.SSSSSで指定。

ユリウス日、および日時フォーマットYYYY-MM-DDTHH:MM:SS.SSSSSで日時を指定できます。
通常の日時形式とユリウス日の変換はこちら。
http://aa.usno.navy.mil/data/docs/JulianDate.html

例:
2005年4月29日9時29分24秒を指定する場合


	time { jd 2453489.89542 }
または
	time { utc "2005-04-29T09:29:24.0000" }


timerate


引数:
rate <数値> (デフォルト 1.0)

rate時間の速さを指定。
なお、0で時間停止、1で通常の速さに設定。
負数を指定すると時間を逆転。

シミュレーションでの時間の速さを変更できます。

例:
速さを1000倍にする場合


	timerate { rate 1000 }


track


引数:
無し

天体を常に画面の中央に表示します。なお、selectで天体が指定されている必要があります。

	cancel   { }
	select   { object "Sol/Earth" }
	goto     { time 3 distance 7 }
	wait     { duration 5 }
	track    { }
	timerate { rate 1000 }

例:


	select { object "Sol/Earth" }
	synchronous { }


unmark


引数:
object <文字列> (デフォルト無し)

objectマーキングを解除したい天体を指定します。

markコマンドでマーキングされた天体のマーキングを解除します。

例:

	unmark { object "Sol/Earth" }


unmarkall


引数:
無し

天体のマーキングをすべて解除します。

例:

	unmarkall { }


wait


引数:
duration <数値> (デフォルト 1.0)

durationで指定された秒数だけ次のコマンドの実行を停止します。
durationに負数を設定するとコマンドは無視されます。

例:

	wait { duration 15.25 }


トップページ > .CELスクリプトガイド > .CELスクリプトコマンド一覧